The Clojure Style Guide

Introduction

Rol modeller önemlidir.

— Officer Alex J. Murphy / RoboCop

Tip	Bu rehberin daha gelişmiş navigasyonlu güzel bir halini https://guide.clojure.style adresinde bulabilirsiniz..

##-- Bu Clojure stil kılavuzu, gerçek dünyadaki Clojure programcılarının diğer gerçek dünya Clojure programcıları tarafından yönetilebilen kod yazabilmeleri için en iyi pratikleri önerir. Gerçek dünya kullanımını yansıtan bir stil kılavuzu kullanılır ve ne kadar iyi olursa olsun, risklerin hiç kullanılmamasına yardımcı olması beklenen insanlar tarafından reddedilen bir ideale bağlı bir stil kılavuzu.

This Clojure style guide recommends best practices so that real-world Clojure programmers can write code that can be maintained by other real-world Clojure programmers. A style guide that reflects real-world usage gets used, and a style guide that holds to an ideal that has been rejected by the people it is supposed to help risks not getting used at all — no matter how good it is.

##-- Kılavuz, ilgili kuralları birkaç bölümüne ayırmıştır. Kuralların arkasına mantığı eklemeye çalıştım (eğer yoksa, çok bariz olduğu varsayımıyla eklenmemiştir).

The guide is separated into several sections of related rules. I’ve tried to add the rationale behind the rules (if it’s omitted, I’ve assumed that it’s pretty obvious).

##-- I didn’t come up with all the rules out of nowhere; they are mostly based on my extensive career as a professional software engineer, feedback and suggestions from members of the Clojure community, and various highly regarded Clojure programming resources, such as "Clojure Programming" and "The Joy of Clojure".

I didn’t come up with all the rules out of nowhere; they are mostly based on my extensive career as a professional software engineer, feedback and suggestions from members of the Clojure community, and various highly regarded Clojure programming resources, such as "Clojure Programming" and "The Joy of Clojure".

Note

The guide is still a work in progress; some sections are missing, others are incomplete, some rules are lacking examples, some rules don’t have examples that illustrate them clearly enough. In due time these issues will be addressed — just keep them in mind for now. Help us address those shortcomings and make this guide better together!

Please note, that the Clojure developing community maintains a list of coding standards for libraries, too.

You can generate a PDF copy of this guide using AsciiDoctor PDF, and an HTML copy with AsciiDoctor using the following commands:

# Generates README.pdf
asciidoctor-pdf -a allow-uri-read README.adoc

# Generates README.html
asciidoctor

Tip	Install the `rouge` gem to get nice syntax highlighting in the generated document. gem install rouge

Translations of the guide are available in the following languages:

Chinese
Japanese
Korean
Portuguese (Under progress)
Russian
Spanish

Source Code Layout & Organization

Nearly everybody is convinced that every style but their own is ugly and unreadable. Leave out the "but their own" and they’re probably right…

— Jerry Coffin (on indentation)

Maximum Line Length

Where feasible, avoid making lines longer than 80 characters.

Why Bother with 80 characters in a World of Modern Widescreen Displays?

A lot of people these days feel that a maximum line length of 80 characters is just a remnant of the past and makes little sense today. After all - modern displays can easily fit 200+ characters on a single line. Still, there are some important benefits to be gained from sticking to shorter lines of code.

First, and foremost - numerous studies have shown that humans read much faster vertically and very long lines of text impede the reading process. As noted earlier, one of the guiding principles of this style guide is to optimize the code we write for human consumption.

Additionally, limiting the required editor window width makes it possible to have several files open side-by-side, and works well when using code review tools that present the two versions in adjacent columns.

The default wrapping in most tools disrupts the visual structure of the code, making it more difficult to understand. The limits are chosen to avoid wrapping in editors with the window width set to 80, even if the tool places a marker glyph in the final column when wrapping lines. Some web based tools may not offer dynamic line wrapping at all.

Some teams strongly prefer a longer line length. For code maintained exclusively or primarily by a team that can reach agreement on this issue, it is okay to increase the line length limit up to 100 characters, or all the way up to 120 characters. Please, restrain the urge to go beyond 120 characters.

Tabs vs Spaces

Use spaces for indentation. No hard tabs.

Body Indentation

Use 2 spaces to indent the bodies of forms that have body parameters. This covers all def forms, special forms and macros that introduce local bindings (e.g. loop, let, when-let) and many macros like when, cond, as->, cond->, case, with-*, etc.

;; good
(when something
  (something-else))

(with-out-str
  (println "Hello, ")
  (println "world!"))

;; bad - four spaces
(when something
    (something-else))

;; bad - one space
(with-out-str
 (println "Hello, ")
 (println "world!"))

Function Arguments Alignment

Vertically align function (macro) arguments spanning multiple lines.

;; good
(filter even?
        (range 1 10))

;; bad
(filter even?
  (range 1 10))

Arguments Indentation

Use a single space indentation for function (macro) arguments when there are no arguments on the same line as the function name.

;; good
(filter
 even?
 (range 1 10))

(or
 ala
 bala
 portokala)

;; bad - two-space indent
(filter
  even?
  (range 1 10))

(or
  ala
  bala
  portokala)

Bindings Alignment

Vertically align let (and let-like) bindings.

;; good
(let [thing1 "some stuff"
      thing2 "other stuff"]
  (foo thing1 thing2))

;; bad
(let [thing1 "some stuff"
  thing2 "other stuff"]
  (foo thing1 thing2))

Map Keys Alignment

Align vertically map keys.

;; good
{:thing1 thing1
 :thing2 thing2}

;; bad
{:thing1 thing1
:thing2 thing2}

;; bad
{:thing1 thing1
  :thing2 thing2}

Line Endings

Use Unix-style line endings.^[1]

Tip	If you’re using Git you might want to add the following configuration setting to protect your project from Windows line endings creeping in: $ git config --global core.autocrlf true

Terminate Files with a Newline

End each file with a newline.

Tip	This should be done by through editor configuration, not manually.

Bracket Spacing

If any text precedes an opening bracket((, { and [) or follows a closing bracket(), } and ]), separate that text from that bracket with a space. Conversely, leave no space after an opening bracket and before following text, or after preceding text and before a closing bracket.

;; good
(foo (bar baz) quux)

;; bad
(foo(bar baz)quux)
(foo ( bar baz ) quux)

No Commas in Sequential Collection Literals

Syntactic sugar causes semicolon cancer.

— Alan Perlis

Don’t use commas between the elements of sequential collection literals.

;; good
[1 2 3]
(1 2 3)

;; bad
[1, 2, 3]
(1, 2, 3)

Optional Commas In Map Literals

Consider enhancing the readability of map literals via judicious use of commas and line breaks.

;; good
{:name "Bruce Wayne" :alter-ego "Batman"}

;; good and arguably a bit more readable
{:name "Bruce Wayne"
 :alter-ego "Batman"}

;; good and arguably more compact
{:name "Bruce Wayne", :alter-ego "Batman"}

Gather Trailing Parentheses

Place all trailing parentheses on a single line instead of distinct lines.

;; good; single line
(when something
  (something-else))

;; bad; distinct lines
(when something
  (something-else)
)

Empty Lines Between Top Level Forms

Use a single empty line between top-level forms.

;; good
(def x ...)

(defn foo ...)

;; bad
(def x ...)
(defn foo ...)

;; bad
(def x ...)


(defn foo ...)

An exception to the rule is the grouping of related defs together.

;; good
(def min-rows 10)
(def max-rows 20)
(def min-cols 15)
(def max-cols 30)

No Blank Lines Within Definition Forms

Do not place blank lines in the middle of a function or macro definition. An exception can be made to indicate grouping of pairwise constructs as found in e.g. let and cond.

No Trailing Whitespace

Avoid trailing whitespace.

One File Per Namespace

Use one file per namespace and one namespace per file.

;; good
(ns foo.bar)

;; bad
(ns foo.bar)
(ns baz.qux)

;; bad
(in-ns quux.quuz)
(in-ns quuz.corge)

;; bad
(ns foo.bar) or (in-ns foo.bar) in multiple files

Namespace Declaration

No Single Segment Namespaces

Avoid single-segment namespaces.

;; good
(ns example.ns)

;; bad
(ns example)

Namespace Segments Limit

Avoid the use of overly long namespaces (i.e., more than 5 segments).

Comprehensive `ns` Form

Start every namespace with a comprehensive ns form, comprised of refers, requires, and imports, conventionally in that order.

(ns examples.ns
  (:refer-clojure :exclude [next replace remove])
  (:require [clojure.string :as s :refer [blank?]])
  (:import java.util.Date))

Line Breaks in `ns`

When there are multiple dependencies, you may want give each one its own line. This facilitates sorting, readability, and cleaner diffs for dependency changes.

;; better
(ns examples.ns
  (:require
   [clojure.string :as s :refer [blank?]]
   [clojure.set :as set]
   [clojure.java.shell :as sh])
  (:import
   java.util.Date
   java.text.SimpleDateFormat
   [java.util.concurrent Executors
                         LinkedBlockingQueue]))

;; good
(ns examples.ns
  (:require [clojure.string :as s :refer [blank?]]
            [clojure.set :as set]
            [clojure.java.shell :as sh])
  (:import java.util.Date
           java.text.SimpleDateFormat
           [java.util.concurrent Executors
                                 LinkedBlockingQueue]))

;; bad
(ns examples.ns
  (:require [clojure.string :as s :refer [blank?]] [clojure.set :as set] [clojure.java.shell :as sh])
  (:import java.util.Date java.text.SimpleDateFormat [java.util.concurrent Executors LinkedBlockingQueue]))

Prefer `:require` Over `:use`

In the ns form prefer :require :as over :require :refer over :require :refer :all. Prefer :require over :use; the latter form should be considered deprecated for new code.

;; good
(ns examples.ns
  (:require [clojure.zip :as zip]))

;; good
(ns examples.ns
  (:require [clojure.zip :refer [lefts rights]]))

;; acceptable as warranted
(ns examples.ns
  (:require [clojure.zip :refer :all]))

;; bad
(ns examples.ns
  (:use clojure.zip))

Sort requirements and imports

In the ns form, sort your requirements and imports. This facilitates readability and avoids duplication, especially when the list of required / imported namespaces is very long.

;; good
(ns examples.ns
  (:require
   [baz.core :as baz]
   [clojure.java.shell :as sh]
   [clojure.set :as set]
   [clojure.string :as s :refer [blank?]]
   [foo.bar :as foo]))

;; bad
(ns examples.ns
  (:require
   [clojure.string :as s :refer [blank?]]
   [clojure.set :as set]
   [baz.core :as baz]
   [foo.bar :as foo]
   [clojure.java.shell :as sh]))

Functions

Optional New Line After Fn Name

Optionally omit the new line between the function name and argument vector for defn when there is no docstring.

;; good
(defn foo
  [x]
  (bar x))

;; good
(defn foo [x]
  (bar x))

;; bad
(defn foo
  [x] (bar x))

Multimethod Dispatch Val Placement

Place the dispatch-val of a multimethod on the same line as the function name.

;; good
(defmethod foo :bar [x] (baz x))

(defmethod foo :bar
  [x]
  (baz x))

;; bad
(defmethod foo
  :bar
  [x]
  (baz x))

(defmethod foo
  :bar [x]
  (baz x))

Oneline Short Fn

Optionally omit the new line between the argument vector and a short function body.

;; good
(defn foo [x]
  (bar x))

;; good for a small function body
(defn foo [x] (bar x))

;; good for multi-arity functions
(defn foo
  ([x] (bar x))
  ([x y]
   (if (predicate? x)
     (bar x)
     (baz x))))

;; bad
(defn foo
  [x] (if (predicate? x)
        (bar x)
        (baz x)))

Multiple Arity Indentation

Indent each arity form of a function definition vertically aligned with its parameters.

;; good
(defn foo
  "I have two arities."
  ([x]
   (foo x 1))
  ([x y]
   (+ x y)))

;; bad - extra indentation
(defn foo
  "I have two arities."
  ([x]
    (foo x 1))
  ([x y]
    (+ x y)))

Multiple Arity Order

Sort the arities of a function from fewest to most arguments. The common case of multi-arity functions is that some K arguments fully specifies the function’s behavior, and that arities N < K partially apply the K arity, and arities N > K provide a fold of the K arity over varargs.

;; good - it's easy to scan for the nth arity
(defn foo
  "I have two arities."
  ([x]
   (foo x 1))
  ([x y]
   (+ x y)))

;; okay - the other arities are applications of the two-arity
(defn foo
  "I have two arities."
  ([x y]
   (+ x y))
  ([x]
   (foo x 1))
  ([x y z & more]
   (reduce foo (foo x (foo y z)) more)))

;; bad - unordered for no apparent reason
(defn foo
  ([x] 1)
  ([x y z] (foo x (foo y z)))
  ([x y] (+ x y))
  ([w x y z & more] (reduce foo (foo w (foo x (foo y z))) more)))

Function Length

Avoid functions longer than 10 LOC (lines of code). Ideally, most functions will be shorter than 5 LOC.

Function Positional Parameters Limit

Avoid parameter lists with more than three or four positional parameters.

Pre and Post Conditions

Prefer function pre and post conditions to checks inside a function’s body.

;; good
(defn foo [x]
  {:pre [(pos? x)]}
  (bar x))

;; bad
(defn foo [x]
  (if (pos? x)
    (bar x)
    (throw (IllegalArgumentException. "x must be a positive number!")))

Idioms

Dynamic Namespace Manipulation

Avoid the use of namespace-manipulating functions like require and refer. They are entirely unnecessary outside of a REPL environment.

Forward References

Avoid forward references. They are occasionally necessary, but such occasions are rare in practice.

Declare

Use declare to enable forward references when forward references are necessary.

Higher-order Functions

Prefer higher-order functions like map to loop/recur.

Vars Inside Functions

Don’t define vars inside functions.

;; very bad
(defn foo []
  (def x 5)
  ...)

Shadowing `clojure.core` Names

Don’t shadow clojure.core names with local bindings.

;; bad - clojure.core/map must be fully qualified inside the function
(defn foo [map]
  ...)

Alter Var Binding

Use alter-var-root instead of def to change the value of a var.

;; good
(def thing 1) ; value of thing is now 1
; do some stuff with thing
(alter-var-root #'thing (constantly nil)) ; value of thing is now nil

;; bad
(def thing 1)
; do some stuff with thing
(def thing nil)
; value of thing is now nil

Nil Punning

Use seq as a terminating condition to test whether a sequence is empty (this technique is sometimes called nil punning).

;; good
(defn print-seq [s]
  (when (seq s)
    (prn (first s))
    (recur (rest s))))

;; bad
(defn print-seq [s]
  (when-not (empty? s)
    (prn (first s))
    (recur (rest s))))

Converting Sequences to Vectors

Prefer vec over into when you need to convert a sequence into a vector.

;; good
(vec some-seq)

;; bad
(into [] some-seq)

`when` vs `if`

Use when instead of (if … (do …)).

;; good
(when pred
  (foo)
  (bar))

;; bad
(if pred
  (do
    (foo)
    (bar)))

`if-let`

Use if-let instead of let + if.

;; good
(if-let [result (foo x)]
  (something-with result)
  (something-else))

;; bad
(let [result (foo x)]
  (if result
    (something-with result)
    (something-else)))

`when-let`

Use when-let instead of let + when.

;; good
(when-let [result (foo x)]
  (do-something-with result)
  (do-something-more-with result))

;; bad
(let [result (foo x)]
  (when result
    (do-something-with result)
    (do-something-more-with result)))

`if-not`

Use if-not instead of (if (not …) …).

;; good
(if-not pred
  (foo))

;; bad
(if (not pred)
  (foo))

`when-not`

Use when-not instead of (when (not …) …).

;; good
(when-not pred
  (foo)
  (bar))

;; bad
(when (not pred)
  (foo)
  (bar))

`when-not` vs `if-not`

Use when-not instead of (if-not … (do …)).

;; good
(when-not pred
  (foo)
  (bar))

;; bad
(if-not pred
  (do
    (foo)
    (bar)))

`not=`

Use not= instead of (not (= …)).

;; good
(not= foo bar)

;; bad
(not (= foo bar))

`printf`

Use printf instead of (print (format …)).

;; good
(printf "Hello, %s!\n" name)

;; ok
(println (format "Hello, %s!" name))

Flexible Comparison Functions

When doing comparisons, keep in mind that Clojure’s functions <, >, etc. accept a variable number of arguments.

;; good
(< 5 x 10)

;; bad
(and (> x 5) (< x 10))

Single Param Fn Literal

Prefer % over %1 in function literals with only one parameter.

;; good
#(Math/round %)

;; bad
#(Math/round %1)

Multiple Params Fn Literal

Prefer %1 over % in function literals with more than one parameter.

;; good
#(Math/pow %1 %2)

;; bad
#(Math/pow % %2)

No Useless Anonymous Fns

Don’t wrap functions in anonymous functions when you don’t need to.

;; good
(filter even? (range 1 10))

;; bad
(filter #(even? %) (range 1 10))

No Multiple Forms Fn Literals

Don’t use function literals if the function body will consist of more than one form.

;; good
(fn [x]
  (println x)
  (* x 2))

;; bad (you need an explicit do form)
#(do (println %)
     (* % 2))

`complement`

Favor the use of complement versus the use of an anonymous function.

;; good
(filter (complement some-pred?) coll)

;; bad
(filter #(not (some-pred? %)) coll)

This rule should obviously be ignored if the complementing predicate exists in the form of a separate function (e.g. even? and odd?).

`comp`

Favor comp over anonymous functions for function composition.

;; Assuming `(:require [clojure.string :as str])`...

;; good
(map #(str/capitalize (str/trim %)) ["top " " test "])

;; better
(map (comp str/capitalize str/trim) ["top " " test "])

`partial`

Favor partial over anonymous functions for currying.

;; good
(map #(+ 5 %) (range 1 10))

;; (arguably) better
(map (partial + 5) (range 1 10))

Threading Macros

Prefer the use of the threading macros -> (thread-first) and ->> (thread-last) to heavy form nesting.

;; good
(-> [1 2 3]
    reverse
    (conj 4)
    prn)

;; not as good
(prn (conj (reverse [1 2 3])
           4))

;; good
(->> (range 1 10)
     (filter even?)
     (map (partial * 2)))

;; not as good
(map (partial * 2)
     (filter even? (range 1 10)))

Threading Macros Alignment

The arguments to the threading macros -> (thread-first) and ->> (thread-last) should line up.

;; good
(->> (range)
     (filter even?)
     (take 5))

;; bad
(->> (range)
  (filter even?)
  (take 5))

Default `cond` Branch

Use :else as the catch-all test expression in cond.

;; good
(cond
  (neg? n) "negative"
  (pos? n) "positive"
  :else "zero")

;; bad
(cond
  (neg? n) "negative"
  (pos? n) "positive"
  true "zero")

`condp` vs `cond`

Prefer condp instead of cond when the predicate & expression don’t change.

;; good
(cond
  (= x 10) :ten
  (= x 20) :twenty
  (= x 30) :thirty
  :else :dunno)

;; much better
(condp = x
  10 :ten
  20 :twenty
  30 :thirty
  :dunno)

`case` vs `cond/condp`

Prefer case instead of cond or condp when test expressions are compile-time constants.

;; good
(cond
  (= x 10) :ten
  (= x 20) :twenty
  (= x 30) :forty
  :else :dunno)

;; better
(condp = x
  10 :ten
  20 :twenty
  30 :forty
  :dunno)

;; best
(case x
  10 :ten
  20 :twenty
  30 :forty
  :dunno)

Short Forms In Cond

Use short forms in cond and related. If not possible give visual hints for the pairwise grouping with comments or empty lines.

;; good
(cond
  (test1) (action1)
  (test2) (action2)
  :else   (default-action))

;; ok-ish
(cond
  ;; test case 1
  (test1)
  (long-function-name-which-requires-a-new-line
    (complicated-sub-form
      (-> 'which-spans multiple-lines)))

  ;; test case 2
  (test2)
  (another-very-long-function-name
    (yet-another-sub-form
      (-> 'which-spans multiple-lines)))

  :else
  (the-fall-through-default-case
    (which-also-spans 'multiple
                      'lines)))

Set As Predicate

Use a set as a predicate when appropriate.

;; good
(remove #{1} [0 1 2 3 4 5])

;; bad
(remove #(= % 1) [0 1 2 3 4 5])

;; good
(count (filter #{\a \e \i \o \u} "mary had a little lamb"))

;; bad
(count (filter #(or (= % \a)
                    (= % \e)
                    (= % \i)
                    (= % \o)
                    (= % \u))
               "mary had a little lamb"))

`inc` and `dec`

Use (inc x) & (dec x) instead of (+ x 1) and (- x 1).

`pos?` and `neg?`

Use (pos? x), (neg? x) & (zero? x) instead of (> x 0), (< x 0) & (= x 0).

`list*` vs `cons`

Use list* instead of a series of nested cons invocations.

;; good
(list* 1 2 3 [4 5])

;; bad
(cons 1 (cons 2 (cons 3 [4 5])))

Sugared Java Interop

Use the sugared Java interop forms.

;;; object creation
;; good
(java.util.ArrayList. 100)

;; bad
(new java.util.ArrayList 100)

;;; static method invocation
;; good
(Math/pow 2 10)

;; bad
(. Math pow 2 10)

;;; instance method invocation
;; good
(.substring "hello" 1 3)

;; bad
(. "hello" substring 1 3)

;;; static field access
;; good
Integer/MAX_VALUE

;; bad
(. Integer MAX_VALUE)

;;; instance field access
;; good
(.someField some-object)

;; bad
(. some-object someField)

Compact Metadata Notation For True Flags

Use the compact metadata notation for metadata that contains only slots whose keys are keywords and whose value is boolean true.

;; good
(def ^:private a 5)

;; bad
(def ^{:private true} a 5)

Private

Denote private parts of your code.

;; good
(defn- private-fun [] ...)

(def ^:private private-var ...)

;; bad
(defn private-fun [] ...) ; not private at all

(defn ^:private private-fun [] ...) ; overly verbose

(def private-var ...) ; not private at all

Access Private Var

To access a private var (e.g. for testing), use the @#'some.ns/var form.

Attach Metadata Carefully

Be careful regarding what exactly you attach metadata to.

;; we attach the metadata to the var referenced by `a`
(def ^:private a {})
(meta a) ;=> nil
(meta #'a) ;=> {:private true}

;; we attach the metadata to the empty hash-map value
(def a ^:private {})
(meta a) ;=> {:private true}
(meta #'a) ;=> nil

Naming

The only real difficulties in programming are cache invalidation and naming things.

— Phil Karlton

Ns Naming Schemas

When naming namespaces favor the following two schemas:

project.module
organization.project.module

Lisp Case Ns

Use lisp-case in composite namespace segments (e.g. bruce.project-euler).

Lisp Case

Use lisp-case for function and variable names.

;; good
(def some-var ...)
(defn some-fun ...)

;; bad
(def someVar ...)
(defn somefun ...)
(def some_fun ...)

Camelcase For Protocols Records Structs And Types

Use CamelCase for protocols, records, structs, and types. (Keep acronyms like HTTP, RFC, XML uppercase.)

Pred With Question Mark

The names of predicate methods (methods that return a boolean value) should end in a question mark (e.g., even?).

;; good
(defn palindrome? ...)

;; bad
(defn palindrome-p ...) ; Common Lisp style
(defn is-palindrome ...) ; Java style

Changing State Fns With Exclamation Mark

The names of functions/macros that are not safe in STM transactions should end with an exclamation mark (e.g. reset!).

Arrow Instead Of To

Use -> instead of to in the names of conversion functions.

;; good
(defn f->c ...)

;; not so good
(defn f-to-c ...)

Earmuffs For Dynamic Vars

Use earmuffs for things intended for rebinding (ie. are dynamic).

;; good
(def ^:dynamic *a* 10)

;; bad
(def ^:dynamic a 10)

Don’t Flag Constants

Don’t use a special notation for constants; everything is assumed a constant unless specified otherwise.

Underscore For Unused Bindings

Use _ for destructuring targets and formal argument names whose value will be ignored by the code at hand.

;; good
(let [[a b _ c] [1 2 3 4]]
  (println a b c))

(dotimes [_ 3]
  (println "Hello!"))

;; bad
(let [[a b c d] [1 2 3 4]]
  (println a b d))

(dotimes [i 3]
  (println "Hello!"))

However, when it can help the understanding of your code, it can be useful to explicitly name unused arguments or maps you’re destructuring from. In this case, prepend the name with an underscore to explicitly signal that the variable is supposed to be unused.

;; good
(defn myfun1 [context _]
 (assoc context :foo "bar"))

(defn myfun2 [context {:keys [id]}]
 (assoc context :user-id id))

;; better
(defn myfun1 [context _user]
 (assoc context :foo "bar"))

(defn myfun2 [context {:keys [id] :as _user}]
 (assoc context :user-id id))

Idiomatic Names

Follow clojure.core's example for idiomatic names like pred and coll.

in functions:
- f, g, h - function input
- n - integer input usually a size
- index, i - integer index
- x, y - numbers
- xs - sequence
- m - map
- s - string input
- re - regular expression
- coll - a collection
- pred - a predicate closure
- & more - variadic input
- xf - xform, a transducer
in macros:
- expr - an expression
- body - a macro body
- binding - a macro binding vector

Data Structures

It is better to have 100 functions operate on one data structure than to have 10 functions operate on 10 data structures.

— Alan J. Perlis

Avoid Lists

Avoid the use of lists for generic data storage (unless a list is exactly what you need).

Keywords For Hash Keys

Prefer the use of keywords for hash keys.

;; good
{:name "Bruce" :age 30}

;; bad
{"name" "Bruce" "age" 30}

Literal Col Syntax

Prefer the use of the literal collection syntax where applicable. However, when defining sets, only use literal syntax when the values are compile-time constants.

;; good
[1 2 3]
#{1 2 3}
(hash-set (func1) (func2)) ; values determined at runtime

;; bad
(vector 1 2 3)
(hash-set 1 2 3)
#{(func1) (func2)} ; will throw runtime exception if (func1) = (func2)

Avoid Index Based Coll Access

Avoid accessing collection members by index whenever possible.

Keywords As Fn To Get Map Values

Prefer the use of keywords as functions for retrieving values from maps, where applicable.

(def m {:name "Bruce" :age 30})

;; good
(:name m)

;; more verbose than necessary
(get m :name)

;; bad - susceptible to NullPointerException
(m :name)

Colls As Fns

Leverage the fact that most collections are functions of their elements.

;; good
(filter #{\a \e \o \i \u} "this is a test")

;; bad - too ugly to share

Keywords As Fns

Leverage the fact that keywords can be used as functions of a collection.

((juxt :a :b) {:a "ala" :b "bala"})

Avoid Transient Colls

Avoid the use of transient collections, except for performance-critical portions of the code.

Avoid Java Colls

Avoid the use of Java collections.

Avoid Java Arrays

Avoid the use of Java arrays, except for interop scenarios and performance-critical code dealing heavily with primitive types.

Types & Records

Record Constructors

Don’t use the interop syntax to construct type and record instances. deftype and defrecord automatically create constructor functions. Use those instead of the interop syntax, as they make it clear that you’re dealing with a deftype or a defrecord. See this article for more details.

(defrecord Foo [a b])
(deftype Bar [a b])

;; good
(->Foo 1 2)
(map->Foo {:b 4 :a 3})
(->Bar 1 2)

;; bad
(Foo. 1 2)
(Bar. 1 2)

Note that deftype doesn’t define the map->Type constructor. It’s available only for records.

Custom Record Constructors

Add custom type/record constructors when needed (e.g. to validate properties on record creation). See this article for more details.

(defrecord Customer [id name phone email])

(defn make-customer
  "Creates a new customer record."
  [{:keys [name phone email]}]
  {:pre [(string? name)
         (valid-phone? phone)
         (valid-email? email)]}
  (->Customer (next-id) name phone email))

Feel free to adopt whatever naming convention or structure you’d like for such custom constructors.

Custom Record Constructors Naming

Don’t override the auto-generated type/record constructor functions. People expect them to have a certain behaviour and changing this behaviour violates the principle of least surprise. See this article for more details.

(defrecord Foo [num])

;; good
(defn make-foo
  [num]
  {:pre [(pos? num)]}
  (->Foo num))

;; bad
(defn ->Foo
  [num]
  {:pre [(pos? num)]}
  (Foo. num))

Mutation

Refs

`io!` Macro

Consider wrapping all I/O calls with the io! macro to avoid nasty surprises if you accidentally end up calling such code in a transaction.

Avoid `ref-set`

Avoid the use of ref-set whenever possible.

(def r (ref 0))

;; good
(dosync (alter r + 5))

;; bad
(dosync (ref-set r 5))

Small Transactions

Try to keep the size of transactions (the amount of work encapsulated in them) as small as possible.

Avoid Short Long Transactions With Same Ref

Avoid having both short- and long-running transactions interacting with the same Ref.

Agents

Agents Send

Use send only for actions that are CPU bound and don’t block on I/O or other threads.

Agents Send Off

Use send-off for actions that might block, sleep, or otherwise tie up the thread.

Atoms

No Updates Within Transactions

Avoid atom updates inside STM transactions.

Prefer `swap!` over `reset!`

Try to use swap! rather than reset!, where possible.

(def a (atom 0))

;; good
(swap! a + 5)

;; not as good
(reset! a 5)

Strings

Prefer Clojure String Over Interop

Prefer string manipulation functions from clojure.string over Java interop or rolling your own.

;; good
(clojure.string/upper-case "bruce")

;; bad
(.toUpperCase "bruce")

Exceptions

Reuse Existing Exception Types

Reuse existing exception types. Idiomatic Clojure code — when it does throw an exception — throws an exception of a standard type (e.g. java.lang.IllegalArgumentException, java.lang.UnsupportedOperationException, java.lang.IllegalStateException, java.io.IOException).

Prefer `with-open` Over `finally`

Favor with-open over finally.

Macros

Don’t Write Macro If Fn Will Do

Don’t write a macro if a function will do.

Write Macro Usage Before Writing The Macro

Create an example of a macro usage first and the macro afterwards.

Break Complicated Macros

Break complicated macros into smaller functions whenever possible.

Macros As Syntactic Sugar

A macro should usually just provide syntactic sugar and the core of the macro should be a plain function. Doing so will improve composability.

Syntax Quoted Forms

Prefer syntax-quoted forms over building lists manually.

Comments

Good code is its own best documentation. As you’re about to add a comment, ask yourself, "How can I improve the code so that this comment isn’t needed?" Improve the code and then document it to make it even clearer.

— Steve McConnell

Self Documenting Code

Endeavor to make your code as self-documenting as possible.

Four Semicolons For Heading Comments

Write heading comments with at least four semicolons.

Three Semicolons For Top Level Comments

Write top-level comments with three semicolons.

Two Semicolons For Code Fragment

Write comments on a particular fragment of code before that fragment and aligned with it, using two semicolons.

One Semicolon For Margin Comments

Write margin comments with one semicolon.

Semicolon Space

Always have at least one space between the semicolon and the text that follows it.

;;;; Frob Grovel

;;; This section of code has some important implications:
;;;   1. Foo.
;;;   2. Bar.
;;;   3. Baz.

(defn fnord [zarquon]
  ;; If zob, then veeblefitz.
  (quux zot
        mumble             ; Zibblefrotz.
        frotz))

English Syntax

Comments longer than a word begin with a capital letter and use punctuation. Separate sentences with one space.

No Superfluous Comments

Avoid superfluous comments.

;; bad
(inc counter) ; increments counter by one

Comment Upkeep

Keep existing comments up-to-date. An outdated comment is worse than no comment at all.

Dash Underscore Reader Macro

Prefer the use of the #_ reader macro over a regular comment when you need to comment out a particular form.

;; good
(+ foo #_(bar x) delta)

;; bad
(+ foo
   ;; (bar x)
   delta)

Refactor Don’t Comment

Good code is like a good joke - it needs no explanation.

— Russ Olsen

Avoid writing comments to explain bad code. Refactor the code to make it self-explanatory. ("Do, or do not. There is no try." --Yoda)

Comment Annotations

Annotate Above

Annotations should usually be written on the line immediately above the relevant code.

;; good
(defn some-fun
  []
  ;; FIXME: Replace baz with the newer bar.
  (baz))

;; bad
;; FIXME: Replace baz with the newer bar.
(defn some-fun
  []
  (baz))

Annotate Keywords

The annotation keyword is followed by a colon and a space, then a note describing the problem.

;; good
(defn some-fun
  []
  ;; FIXME: Replace baz with the newer bar.
  (baz))

;; bad - no colon after annotation
(defn some-fun
  []
  ;; FIXME Replace baz with the newer bar.
  (baz))

;; bad - no space after colon
(defn some-fun
  []
  ;; FIXME:Replace baz with the newer bar.
  (baz))

Indent Annotations

If multiple lines are required to describe the problem, subsequent lines should be indented as much as the first one.

;; good
(defn some-fun
  []
  ;; FIXME: This has crashed occasionally since v1.2.3. It may
  ;;        be related to the BarBazUtil upgrade. (xz 13-1-31)
  (baz))

;; bad
(defn some-fun
  []
  ;; FIXME: This has crashed occasionally since v1.2.3. It may
  ;; be related to the BarBazUtil upgrade. (xz 13-1-31)
  (baz))

Sign And Date Annotations

Tag the annotation with your initials and a date so its relevance can be easily verified.

(defn some-fun
  []
  ;; FIXME: This has crashed occasionally since v1.2.3. It may
  ;;        be related to the BarBazUtil upgrade. (xz 13-1-31)
  (baz))

Rare Eol Annotations

In cases where the problem is so obvious that any documentation would be redundant, annotations may be left at the end of the offending line with no note. This usage should be the exception and not the rule.

(defn bar
  []
  (sleep 100)) ; OPTIMIZE

`TODO`

Use TODO to note missing features or functionality that should be added at a later date.

`FIXME`

Use FIXME to note broken code that needs to be fixed.

`OPTIMIZE`

Use OPTIMIZE to note slow or inefficient code that may cause performance problems.

`HACK`

Use HACK to note "code smells" where questionable coding practices were used and should be refactored away.

`REVIEW`

Use REVIEW to note anything that should be looked at to confirm it is working as intended. For example: REVIEW: Are we sure this is how the client does X currently?

Document Custom Annotations

Use other custom annotation keywords if it feels appropriate, but be sure to document them in your project’s README or similar.

Documentation

Docstrings are the primary way to document Clojure code. Many definition forms (e.g. def, defn, defmacro, ns) support docstrings and usually it’s a good idea to make good use of them, regardless of whether the var in question is something public or private.

If a definition form doesn’t support docstrings directly you can still supply them via the :doc metadata attribute.

This section outlines some of the common conventions and best practices for documenting Clojure code.

Prefer Docstrings

If a form supports docstrings directly prefer them over using :doc metadata:

;; good
(defn foo
  "This function doesn't do much."
  []
  ...)

(ns foo.bar.core
  "That's an awesome library.")

;; bad
(defn foo
  ^{:doc "This function doesn't do much."}
  []
  ...)

(ns ^{:doc "That's an awesome library.")
  foo.bar.core)

Docstring Summary

Let the first line in the docstring be a complete, capitalized sentence which concisely describes the var in question. This makes it easy for tooling (Clojure editors and IDEs) to display a short a summary of the docstring at various places.

;; good
(defn frobnitz
  "This function does a frobnitz.
  It will do gnorwatz to achieve this, but only under certain
  circumstances."
  []
  ...)

;; bad
(defn frobnitz
  "This function does a frobnitz. It will do gnorwatz to
  achieve this, but only under certain circumstances."
  []
  ...)

Leverage Markdown in Docstrings

Important tools such as cljdoc support Markdown in docstrings so leverage it for nicely formatted documentation.

;; good
(defn qzuf-number
  "Computes the [Qzuf number](https://wikipedia.org/qzuf) of the `coll`.
  Supported options in `opts`:

  | key           | description |
  | --------------|-------------|
  | `:finite-uni?`| Assume finite universe; default: `false`
  | `:complex?`   | If OK to return a [complex number](https://en.wikipedia.org/wiki/Complex_number); default: `false`
  | `:timeout`    | Throw an exception if the computation doesn't finish within `:timeout` milliseconds; default: `nil`

  Example:
  ```clojure
  (when (neg? (qzuf-number [1 2 3] {:finite-uni? true}))
    (throw (RuntimeException. "Error in the Universe!")))
  ```"
  [coll opts]
  ...)

Document Positional Arguments

Document all positional arguments, and wrap them them with backticks (`) so that editors and IDEs can identify them and potentially provide extra functionality for them.

;; good
(defn watsitz
  "Watsitz takes a `frob` and converts it to a znoot.
  When the `frob` is negative, the znoot becomes angry."
  [frob]
  ...)

;; bad
(defn watsitz
  "Watsitz takes a frob and converts it to a znoot.
  When the frob is negative, the znoot becomes angry."
  [frob]
  ...)

Document References

Wrap any var references in the docstring with ` so that tooling can identify them. Wrap them with [[..]] if you want to link to them.

;; good
(defn wombat
  "Acts much like `clojure.core/identity` except when it doesn't.
  Takes `x` as an argument and returns that. If it feels like it.
  See also [[kangaroo]]."
  [x]
  ...)

;; bad
(defn wombat
  "Acts much like clojure.core/identity except when it doesn't.
  Takes `x` as an argument and returns that. If it feels like it.
  See also kangaroo."
  [x]
  ...)

Docstring Grammar

Docstrings should be composed of well-formed English sentences. Every sentence should start with a capitalized word, be gramatically coherent, and end with appropriate punctuation. Sentences should be separated with a single space.

;; good
(def foo
  "All sentences should end with a period (or maybe an exclamation mark).
  The sentence should be followed by a space, unless it concludes the docstring.")

;; bad
(def foo
  "all sentences should end with a period (or maybe an exclamation mark).
  The sentence should be followed by a space, unless it concludes the docstring.")

Docstring Indentation

Indent multi-line docstrings by two spaces.

;; good
(ns my.ns
  "It is actually possible to document a ns.
  It's a nice place to describe the purpose of the namespace and maybe even
  the overall conventions used. Note how _not_ indenting the docstring makes
  it easier for tooling to display it correctly.")

;; bad
(ns my.ns
  "It is actually possible to document a ns.
It's a nice place to describe the purpose of the namespace and maybe even
the overall conventions used. Note how _not_ indenting the docstring makes
it easier for tooling to display it correctly.")

Docstring Leading Trailing Whitespace

Neither start nor end your docstrings with any whitespace.

;; good
(def foo
  "I'm so awesome."
  42)

;; bad
(def silly
  "    It's just silly to start a docstring with spaces.
  Just as silly as it is to end it with a bunch of them.      "
  42)

Docstring After Fn Name

When adding a docstring — especially to a function using the above form — take care to correctly place the docstring after the function name, not after the argument vector. The latter is not invalid syntax and won’t cause an error, but includes the string as a form in the function body without attaching it to the var as documentation.

;; good
(defn foo
  "docstring"
  [x]
  (bar x))

;; bad
(defn foo [x]
  "docstring"
  (bar x))

Existential

Be Functional

Code in a functional way, using mutation only when it makes sense.

Be Consistent

Be consistent. In an ideal world, be consistent with these guidelines.

Common Sense

Use common sense.

Testing

Test Directory Structure

Store your tests in a separate directory, typically test/yourproject/ (as opposed to src/yourproject/). Your build tool is responsible for making them available in the contexts where they are necessary; most templates will do this for you automatically.

Test Namespace Naming

Name your ns yourproject.something-test, a file which usually lives in test/yourproject/something_test.clj (or .cljc, cljs).

Test Naming

When using clojure.test, define your tests with deftest and name them something-test.

;; good
(deftest something-test ...)

;; bad
(deftest something-tests ...)
(deftest test-something ...)
(deftest something ...)

Library Organization

Library Coordinates

If you are publishing libraries to be used by others, make sure to follow the Central Repository guidelines for choosing your groupId and artifactId. This helps to prevent name conflicts and facilitates the widest possible use. A good example is Component - its coordinates are com.stuartsierra/component.

Another approach that’s popular in the wild is to use a project (or organization) name as the groupId instead of domain name. Examples of such naming would be:

cider/cider-nrepl
nrepl/nrepl
nrepl/drawbridge
clj-commons/fs

Minimize Dependencies

Avoid unnecessary dependencies. For example, a three-line utility function copied into a project is usually better than a dependency that drags in hundreds of vars you do not plan to use.

Tool-agnostic

Deliver core functionality and integration points in separate artifacts. That way, consumers can consume your library without being constrained by your unrelated tooling preferences. For example, Component provides core functionality, and reloaded provides leiningen integration.

Lint Tools

There are some lint tools created by the Clojure community that might aid you in your endeavor to write idiomatic Clojure code.

Slamhound is a tool that will automatically generate proper ns declarations from your existing code.
kibit is a static code analyzer for Clojure which uses core.logic to search for patterns of code for which there might exist a more idiomatic function or macro.
clj-kondo is a linter that detects a wide number of discouraged patterns and suggests improvements, based on this style guide.

Contributing

Nothing written in this guide is set in stone. It’s my desire to work together with everyone interested in Clojure coding style, so that we could ultimately create a resource that will be beneficial to the entire Clojure community.

Feel free to open pull requests with improvements. Thanks in advance for your help!

You can also support the style guide (and all my Clojure projects like CIDER, nREPL, orchard, etc) with financial contributions via Patreon and PayPal.

License

This work is licensed under a Creative Commons Attribution 3.0 Unported License

Spread the Word

A community-driven style guide is of little use to a community that doesn’t know about its existence. Tweet about the guide, share it with your friends and colleagues. Every comment, suggestion or opinion we get makes the guide just a little bit better. And we want to have the best possible guide, don’t we?

1. *BSD/Solaris/Linux/OSX users are covered by default, Windows users have to be extra careful.

Provide feedback

Saved searches

Use saved searches to filter your results more quickly

Uh oh!