feat: Add rule object_shorthand (#90)

MrMcGoats · web-flow · commit d586228214fc · 2020-09-23T08:14:37.000-05:00
diff --git a/src/coffeelint.coffee b/src/coffeelint.coffee
@@ -226,6 +226,7 @@ coffeelint.registerRule require './rules/no_this.coffee'
 coffeelint.registerRule require './rules/eol_last.coffee'
 coffeelint.registerRule require './rules/no_private_function_fat_arrows.coffee'
 coffeelint.registerRule require './rules/missing_parseint_radix.coffee'
+coffeelint.registerRule require './rules/object_shorthand.coffee'
 
 getTokens = (source) ->
     try
diff --git a/src/rules/object_shorthand.coffee b/src/rules/object_shorthand.coffee
@@ -0,0 +1,39 @@
+module.exports = class ObjectShorthand
+    rule:
+        name: 'object_shorthand'
+        level: 'ignore'
+        message: 'Use property-value shorthand when using explicit braces'
+        description: '''
+        <p>Use property value shorthand in objects, when explicit braces are used.</p>
+        <pre><code>test = "value"
+
+        # Good
+        {test}
+        test: test
+
+        # Bad
+        {test: test}
+        </code></pre>
+        '''
+
+    tokens: [':']
+
+    lintToken: (token, tokenApi) ->
+        checkExplicit = ->
+            current = -2
+            while tokenApi.peek(current)[0] isnt '{'
+                current--
+
+            return not tokenApi.peek(current).generated
+
+        # Get the property name and the value
+        property = tokenApi.peek -1
+        value = tokenApi.peek 1
+
+        # Check if we have explicit {}
+        explicit = checkExplicit()
+
+        if explicit and property[1] is value[1]
+            context: "Use '{#{property[1]}}'"
+        else
+            null
diff --git a/test/test_object_shorthand.coffee b/test/test_object_shorthand.coffee
@@ -0,0 +1,45 @@
+path = require 'path'
+vows = require 'vows'
+assert = require 'assert'
+coffeelint = require path.join('..', 'lib', 'coffeelint')
+
+RULE = 'object_shorthand'
+
+vows.describe(RULE).addBatch({
+
+    'Object property-value shorthand':
+        topic:
+            '''
+            test = 'value'
+            a = {test: test}
+            b = {
+              t: 1
+              tt: 2
+              test: test
+            }
+
+            c = test: test
+            '''
+
+        'not required by default': (source) ->
+            errors = coffeelint.lint(source)
+            assert.isArray(errors)
+            assert.isEmpty(errors)
+
+        'can be required': (source) ->
+            config = object_shorthand: { level: 'error' }
+            errors = coffeelint.lint(source, config)
+            assert.isArray(errors)
+            assert.lengthOf(errors, 2)
+            
+            error = errors[0]
+            assert.equal(error.lineNumber, 2)
+            assert.equal(error.message, 'Use property-value shorthand when using explicit braces')
+            assert.equal(error.rule, RULE)
+            
+            error = errors[1]
+            assert.equal(error.lineNumber, 6)
+            assert.equal(error.message, 'Use property-value shorthand when using explicit braces')
+            assert.equal(error.rule, RULE)
+
+}).export(module)
